📂 Advanced File Manager

Multi-Root Navigation System

⬆ Ke Atas 🏠 Root Server 🏠 Root App 🔄 Refresh

📍 Lokasi: /usr/share/vim/vim82/indent 💾 Free: 45.8 GB

⚠️ Direktori ini tidak writable.

✏️ Mengedit: dtd.vim

" Vim indent file
" Language:    	    DTD (Document Type Definition for XML)
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2011-07-08

setlocal indentexpr=GetDTDIndent()
setlocal indentkeys=!^F,o,O,>
setlocal nosmartindent

if exists("*GetDTDIndent")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

" TODO: Needs to be adjusted to stop at [, <, and ].
let s:token_pattern = '^[^[:space:]]\+'

function s:lex1(input, start, ...)
  let pattern = a:0 > 0 ? a:1 : s:token_pattern
  let start = matchend(a:input, '^\_s*', a:start)
  if start == -1
    return ["", a:start]
  endif
  let end = matchend(a:input, pattern, start)
  if end == -1
    return ["", a:start]
  endif
  let token = strpart(a:input, start, end - start)
  return [token, end]
endfunction

function s:lex(input, start, ...)
  let pattern = a:0 > 0 ? a:1 : s:token_pattern
  let info = s:lex1(a:input, a:start, pattern)
  while info[0] == '--'
    let info = s:lex1(a:input, info[1], pattern)
    while info[0] != "" && info[0] != '--'
      let info = s:lex1(a:input, info[1], pattern)
    endwhile
    if info[0] == ""
      return info
    endif
    let info = s:lex1(a:input, info[1], pattern)
  endwhile
  return info
endfunction

function s:indent_to_innermost_parentheses(line, end)
  let token = '('
  let end = a:end
  let parentheses = [end - 1]
  while token != ""
    let [token, end] = s:lex(a:line, end, '^\%([(),|]\|[A-Za-z0-9_-]\+\|#P\=CDATA\|%[A-Za-z0-9_-]\+;\)[?*+]\=')
    if token[0] == '('
      call add(parentheses, end - 1)
    elseif token[0] == ')'
      if len(parentheses) == 1
        return [-1, end]
      endif
      call remove(parentheses, -1)
    endif
  endwhile
  return [parentheses[-1] - strridx(a:line, "\n", parentheses[-1]), end]
endfunction

" TODO: Line and end could be script global (think OO members).
function GetDTDIndent()
  if v:lnum == 1
    return 0
  endif
  
  " Begin by searching back for a <! that isn’t inside a comment.
  " From here, depending on what follows immediately after, parse to
  " where we’re at to determine what to do.
  if search('<!', 'bceW') == 0
    return indent(v:lnum - 1)
  endif
  let lnum = line('.')
  let col = col('.')
  let indent = indent('.')
  let line = lnum == v:lnum ? getline(lnum) : join(getline(lnum, v:lnum - 1), "\n")

let [declaration, end] = s:lex1(line, col)
  if declaration == ""
    return indent + shiftwidth()
  elseif declaration == '--'
    " We’re looking at a comment.  Now, simply determine if the comment is
    " terminated or not.  If it isn’t, let Vim take care of that using
    " 'comments' and 'autoindent'. Otherwise, indent to the first lines level.
    while declaration != ""
      let [declaration, end] = s:lex(line, end)
      if declaration == "-->"
        return indent
      endif
    endwhile
    return -1
  elseif declaration == 'ELEMENT'
    " Check for element name.  If none exists, indent one level.
    let [name, end] = s:lex(line, end)
    if name == ""
      return indent + shiftwidth()
    endif

" Check for token following element name.  This can be a specification of
    " whether the start or end tag may be omitted.  If nothing is found, indent
    " one level.
    let [token, end] = s:lex(line, end, '^\%([-O(]\|ANY\|EMPTY\)')
    let n = 0
    while token =~ '[-O]' && n < 2
      let [token, end] = s:lex(line, end, '^\%([-O(]\|ANY\|EMPTY\)')
      let n += 1
    endwhile
    if token == ""
      return indent + shiftwidth()
    endif

" Next comes the content model.  If the token we’ve found isn’t a
    " parenthesis it must be either ANY, EMPTY or some random junk.  Either
    " way, we’re done indenting this element, so set it to that of the first
    " line so that the terminating “>” winds up having the same indention.
    if token != '('
      return indent
    endif

" Now go through the content model.  We need to keep track of the nesting
    " of parentheses.  As soon as we hit 0 we’re done.  If that happens we must
    " have a complete content model.  Thus set indention to be the same as that
    " of the first line so that the terminating “>” winds up having the same
    " indention.  Otherwise, we’ll indent to the innermost parentheses not yet
    " matched.
    let [indent_of_innermost, end] = s:indent_to_innermost_parentheses(line, end)
    if indent_of_innermost != -1
      return indent_of_innermost
    endif

" Finally, look for any additions and/or exceptions to the content model.
    " This is defined by a “+” or “-” followed by another content model
    " declaration.
    " TODO: Can the “-” be separated by whitespace from the “(”?
    let seen = { '+(': 0, '-(': 0 }
    while 1
      let [additions_exceptions, end] = s:lex(line, end, '^[+-](')
      if additions_exceptions != '+(' && additions_exceptions != '-('
        let [token, end] = s:lex(line, end)
        if token == '>'
          return indent
        endif
        " TODO: Should use s:lex here on getline(v:lnum) and check for >.
        return getline(v:lnum) =~ '^\s*>' || count(values(seen), 0) == 0 ? indent : (indent + shiftwidth())
      endif

" If we’ve seen an addition or exception already and this is of the same
      " kind, the user is writing a broken DTD.  Time to bail.
      if seen[additions_exceptions]
        return indent
      endif
      let seen[additions_exceptions] = 1

let [indent_of_innermost, end] = s:indent_to_innermost_parentheses(line, end)
      if indent_of_innermost != -1
        return indent_of_innermost
      endif
    endwhile
  elseif declaration == 'ATTLIST'
    " Check for element name.  If none exists, indent one level.
    let [name, end] = s:lex(line, end)
    if name == ""
      return indent + shiftwidth()
    endif

" Check for any number of attributes.
    while 1
      " Check for attribute name.  If none exists, indent one level, unless the
      " current line is a lone “>”, in which case we indent to the same level
      " as the first line.  Otherwise, if the attribute name is “>”, we have
      " actually hit the end of the attribute list, in which case we indent to
      " the same level as the first line.
      let [name, end] = s:lex(line, end)
      if name == ""
        " TODO: Should use s:lex here on getline(v:lnum) and check for >.
        return getline(v:lnum) =~ '^\s*>' ? indent : (indent + shiftwidth())
      elseif name == ">"
        return indent
      endif

" Check for attribute value declaration.  If none exists, indent two
      " levels.  Otherwise, if it’s an enumerated value, check for nested
      " parentheses and indent to the innermost one if we don’t reach the end
      " of the listc.  Otherwise, just continue with looking for the default
      " attribute value.
      " TODO: Do validation of keywords
      " (CDATA|NMTOKEN|NMTOKENS|ID|IDREF|IDREFS|ENTITY|ENTITIES)?
      let [value, end] = s:lex(line, end, '^\%((\|[^[:space:]]\+\)')
      if value == ""
        return indent + shiftwidth() * 2
      elseif value == 'NOTATION'
        " If this is a enumerated value based on notations, read another token
        " for the actual value.  If it doesn’t exist, indent three levels.
        " TODO: If validating according to above, value must be equal to '('.
        let [value, end] = s:lex(line, end, '^\%((\|[^[:space:]]\+\)')
        if value == ""
          return indent + shiftwidth() * 3
        endif
      endif

if value == '('
        let [indent_of_innermost, end] = s:indent_to_innermost_parentheses(line, end)
        if indent_of_innermost != -1
          return indent_of_innermost
        endif
      endif

" Finally look for the attribute’s default value.  If non exists, indent
      " two levels.
      let [default, end] = s:lex(line, end, '^\%("\_[^"]*"\|#\(REQUIRED\|IMPLIED\|FIXED\)\)')
      if default == ""
        return indent + shiftwidth() * 2
      elseif default == '#FIXED'
        " We need to look for the fixed value.  If non exists, indent three
        " levels.
        let [default, end] = s:lex(line, end, '^"\_[^"]*"')
        if default == ""
          return indent + shiftwidth() * 3
        endif
      endif
    endwhile
  elseif declaration == 'ENTITY'
    " Check for entity name.  If none exists, indent one level.  Otherwise, if
    " the name actually turns out to be a percent sign, “%”, this is a
    " parameter entity.  Read another token to determine the entity name and,
    " again, if none exists, indent one level.
    let [name, end] = s:lex(line, end)
    if name == ""
      return indent + shiftwidth()
    elseif name == '%'
      let [name, end] = s:lex(line, end)
      if name == ""
        return indent + shiftwidth()
      endif
    endif

" Now check for the entity value.  If none exists, indent one level.  If it
    " does exist, indent to same level as first line, as we’re now done with
    " this entity.
    "
    " The entity value can be a string in single or double quotes (no escapes
    " to worry about, as entities are used instead).  However, it can also be
    " that this is an external unparsed entity.  In that case we have to look
    " further for (possibly) a public ID and an URI followed by the NDATA
    " keyword and the actual notation name.  For the public ID and URI, indent
    " two levels, if they don’t exist.  If the NDATA keyword doesn’t exist,
    " indent one level.  Otherwise, if the actual notation name doesn’t exist,
    " indent two level.  If it does, indent to same level as first line, as
    " we’re now done with this entity.
    let [value, end] = s:lex(line, end)
    if value == ""
      return indent + shiftwidth()
    elseif value == 'SYSTEM' || value == 'PUBLIC'
      let [quoted_string, end] = s:lex(line, end, '\%("[^"]\+"\|''[^'']\+''\)')
      if quoted_string == ""
        return indent + shiftwidth() * 2
      endif

if value == 'PUBLIC'
        let [quoted_string, end] = s:lex(line, end, '\%("[^"]\+"\|''[^'']\+''\)')
        if quoted_string == ""
          return indent + shiftwidth() * 2
        endif
      endif

let [ndata, end] = s:lex(line, end)
      if ndata == ""
        return indent + shiftwidth()
      endif

let [name, end] = s:lex(line, end)
      return name == "" ? (indent + shiftwidth() * 2) : indent
    else
      return indent
    endif
  elseif declaration == 'NOTATION'
    " Check for notation name.  If none exists, indent one level.
    let [name, end] = s:lex(line, end)
    if name == ""
      return indent + shiftwidth()
    endif

" Now check for the external ID.  If none exists, indent one level.
    let [id, end] = s:lex(line, end)
    if id == ""
      return indent + shiftwidth()
    elseif id == 'SYSTEM' || id == 'PUBLIC'
      let [quoted_string, end] = s:lex(line, end, '\%("[^"]\+"\|''[^'']\+''\)')
      if quoted_string == ""
        return indent + shiftwidth() * 2
      endif

if id == 'PUBLIC'
        let [quoted_string, end] = s:lex(line, end, '\%("[^"]\+"\|''[^'']\+''\|>\)')
        if quoted_string == ""
          " TODO: Should use s:lex here on getline(v:lnum) and check for >.
          return getline(v:lnum) =~ '^\s*>' ? indent : (indent + shiftwidth() * 2)
        elseif quoted_string == '>'
          return indent
        endif
      endif
    endif

return indent
  endif

" TODO: Processing directives could be indented I suppose.  But perhaps it’s
  " just as well to let the user decide how to indent them (perhaps extending
  " this function to include proper support for whatever processing directive
  " language they want to use).

" Conditional sections are simply passed along to let Vim decide what to do
  " (and hence the user).
  return -1
endfunction

let &cpo = s:cpo_save
unlet s:cpo_save

❌ Batal

Nama	Ukuran	Dimodifikasi	Permission	Aksi
📎 aap.vim	265 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 ada.vim	11 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 ant.vim	290 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 automake.vim	243 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 awk.vim	7.6 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 bash.vim	350 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 bib.vim	346 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 bst.vim	1.9 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 bzl.vim	2.4 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 c.vim	325 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 cdl.vim	4.2 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 ch.vim	470 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 chaiscript.vim	1.1 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 changelog.vim	264 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 clojure.vim	11.4 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 cmake.vim	2.6 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 cobol.vim	8.5 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 config.vim	2.1 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 context.vim	752 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 cpp.vim	329 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 cs.vim	1.7 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 css.vim	1.7 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 cucumber.vim	2.6 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 cuda.vim	305 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 d.vim	510 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 dictconf.vim	337 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 dictdconf.vim	338 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 docbk.vim	336 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 dosbatch.vim	1.3 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 dtd.vim	11.6 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 dtrace.vim	451 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 dune.vim	332 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 dylan.vim	2.6 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 eiffel.vim	3.2 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 elm.vim	3.1 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 erlang.vim	48.9 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 eruby.vim	2.9 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 eterm.vim	668 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 falcon.vim	13.7 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 fortran.vim	7.5 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 framescript.vim	816 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 gitconfig.vim	841 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 gitolite.vim	1.2 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 go.vim	1.6 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 haml.vim	2.2 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 hamster.vim	1.4 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 hog.vim	1.8 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 html.vim	32.8 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 htmldjango.vim	273 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 idlang.vim	1.6 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 ishd.vim	1.8 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 j.vim	1.8 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 java.vim	4.2 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 javascript.vim	15 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 javascriptreact.vim	109 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 json.vim	4.4 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 jsp.vim	462 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 ld.vim	1.8 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 less.vim	243 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 lifelines.vim	637 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 liquid.vim	1.9 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 lisp.vim	353 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 logtalk.vim	1.8 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 lua.vim	1.9 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 mail.vim	308 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 make.vim	3.4 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 matlab.vim	4.7 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 meson.vim	5.1 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 mf.vim	156 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 mma.vim	2.2 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 mp.vim	11.1 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 nsis.vim	3.2 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 objc.vim	1.6 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 ocaml.vim	9 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 occam.vim	4.5 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 pascal.vim	5.5 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 perl.vim	5.8 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 perl6.vim	3.5 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 php.vim	25.3 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 postscr.vim	1.6 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 pov.vim	2.6 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 prolog.vim	1.8 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 pyrex.vim	326 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 python.vim	6.8 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 r.vim	13.7 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 raml.vim	285 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 readline.vim	711 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📄 README.txt	1.6 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 rhelp.vim	2.8 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 rmd.vim	1.6 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 rnoweb.vim	1.1 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 rpl.vim	1.8 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 rrst.vim	1.2 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 rst.vim	1.8 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 ruby.vim	29.4 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 rust.vim	6.3 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 sas.vim	5.1 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 sass.vim	950 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 scala.vim	19 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 scheme.vim	372 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 scss.vim	191 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 sdl.vim	2.7 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 sh.vim	9.1 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 sml.vim	6.3 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 sql.vim	1.2 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 sqlanywhere.vim	13.1 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 sshconfig.vim	796 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 systemd.vim	205 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 systemverilog.vim	8.4 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 tcl.vim	2.5 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 tcsh.vim	1.2 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 teraterm.vim	1.3 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 tex.vim	13.4 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 tf.vim	1.5 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 tilde.vim	1013 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 treetop.vim	707 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 typescript.vim	14.1 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 vb.vim	2 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 verilog.vim	8 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 vhdl.vim	14.3 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 vim.vim	5.6 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 vroom.vim	379 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 wast.vim	458 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 xf86conf.vim	709 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 xhtml.vim	269 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 xinetd.vim	1.2 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 xml.vim	7.4 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 xsd.vim	253 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 xslt.vim	297 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 yacc.vim	781 B	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 yaml.vim	5.3 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 zimbu.vim	3.8 KB	2026-06-25 00:16	0644	✏️ Edit ⬇
📎 zsh.vim	411 B	2026-06-25 00:16	0644	✏️ Edit ⬇

📂 Advanced File Manager

✏️ Mengedit: dtd.vim

✍️ Rename: